Memory Leak

[Clootie]

One more variant: "Original split - optimized"

First case (VERY long string):

   928 (total items: 110121) - Original split
    64 (total items: 110110) - DelimitedText split
   427 (total items: 110121) - Harry Hunt split
    62 (total items: 110121) - Original split - optimized  (!)

Second case (MANY average strings):

   125 (total items: 111111) - Original split
    66 (total items: 110110) - DelimitedText split
   405 (total items: 111111) - Harry Hunt split
    64 (total items: 111111) - Original split - optimized   (!)

:lol: :lol: :lol: :lol: :lol: :lol:

CODE:
[pascal]
function TForm1.Split_4(const Source, Delimiter: String): TStringList;
var
DelLength: Integer;
SearchPos, FoundAt: Integer;
begin
Result := TStringList.Create;
DelLength:= Length(Delimiter);
SearchPos:= 1; // initialize it

FoundAt:= PosEx(Delimiter, Source, SearchPos);
while FoundAt > 0 do
begin
Result.Add(Copy(Source, SearchPos, FoundAt - SearchPos));
SearchPos:= FoundAt + DelLength;
FoundAt:= PosEx(Delimiter, Source, SearchPos);
end;

Result.Add(Copy(Source, SearchPos, MaxInt));
end;
[/pascal]

[xGTx]

So now it's xGTx's CLOOTIE Optimized Split version that wins? haha

Clootie, your a genious! thats pretty dang fast.

But now im thinking, as Harry said, delimiting by a string may be a bit slower... What if we change that new split function to delimit by a single char only.

[Clootie]

But now im thinking, as Harry said, delimiting by a string may be a bit slower... What if we change that new split function to delimit by a single char only.

Well, this will be your home work for tomorrow

[xGTx]

Results: [Length of string split: 720036]
 Clootie Optimized Original                    172ms
 My un-optimized clootie optimized of original 266ms

Alright i tried out by char and obviously its slower. So, CLOOTIE WINS

[Clootie]

Why..? Why you wrote it..!

[pascal]function TForm1.Split_5(const Source, Delimiter: String): TStringList;
var
SourceLength: Integer;
SearchPos, FoundAt: Integer;
Delim: Char;
begin
Assert(Length(Delimiter) = 1); // !
Delim:= Delimiter[1];
Result := TStringList.Create;
SourceLength:= Length(Source);
SearchPos:= 1; // initialize it
FoundAt:= 1;

while (FoundAt <= SourceLength) do
begin
if Source[FoundAt] = Delim then
begin
Result.Add(Copy(Source, SearchPos, FoundAt - SearchPos));
Inc(FoundAt);
SearchPos:= FoundAt;
end;
Inc(FoundAt);
end;

Result.Add(Copy(Source, SearchPos, MaxInt));
end;
[/pascal]

[xGTx]

You optimized it!

If i create a string list... Can i use it multiple times before freeing it (in the same function call) or do i have to free it each time i load new data set in it?

Edit:

I don't understand... My loading function is not freeing my string lists even though im clearly freeing them in the code! Ive managed to use 1.6 GB of ram in 60 seconds of loading. <--- Im talking about with the Split() function.. Clooties version. I tried it thru a few tests and it doesn't leak any memory, but in my load function it leaks tons. I went from Split back to Delphi's Delimited way and its not leaking anymore. So it's definitly the split function for some odd reason.

With Clootie's Optimized split:

GTRPG Server Runtime Environment 0.3.5.0
Loading Data.
Loading Maps.
2025 maps loaded in 64 seconds.
Initializing Players. Maximum: 500
Socket awaiting connections.

1.6 GB of RAM used.

With Delphi's delimited:

GTRPG Server Runtime Environment 0.3.5.0
Loading Data.
Loading Maps.
2025 maps loaded in 52 seconds.
Initializing Players. Maximum: 500
Socket awaiting connections.

157 MB of RAM used.

But heres the code: Obviously i have the Split() parts commented out replaced by delphi's delimit
[pascal]
tSplit := TStringList.Create;
nSplit := TStringList.Create;
gSplit := TStringList.Create;

//tSplit := Split(Buffer, '^');
tSplit.Delimiter := '^';
tSplit.DelimitedText := Buffer;


SetLength(Buffer,0);

K := 0;

For X := 0 to MAP_WIDTH do
For Y := 0 to MAP_HEIGHT do
Begin
//nSplit := Split(tSplit.Strings[K], ',');
nSplit.Delimiter := ',';
nSplit.DelimitedText := tSplit.Strings[K];
Inc(K);

// - Bunch of Map stuff loaded here -

if nSplit.Count = 17 Then
begin
//gSplit := Split(nSplit.Strings[16],'|');
gSplit.Delimiter := '|';
gSplit.DelimitedText := nSplit.Strings[16];
for B := 0 to gSplit.Count - 1 Do
begin
Int := StrToInt(gSplit.Strings[B]);
// - More map Stuff -
end;
end;
end;

tSplit.Free;
gSplit.Free;
nSplit.Free;

Result := True;[/pascal]


Now, im no Delphi expert, far from it in-fact but one thing that does cross my mind... In the split function we have
[pascal]Result := TStringList.Create;[/pascal]
That kind of makes me believe a copy of the string list is being created and obviously never freed... I may be far off here but just a thought.

Somewhat supporting my theory, I goto MSX's suggestion of passing the already made TStringList as a parameter and it again works, fast, and no memory leak!
[pascal]procedure Split(const Source, Delimiter: String; CopyTo : TStringList);
var
DelLength: Integer;
SearchPos, FoundAt: Integer;
begin
//Result := TStringList.Create;
DelLength:= Length(Delimiter);
SearchPos:= 1; // initialize it

FoundAt:= PosEx(Delimiter, Source, SearchPos);
while FoundAt > 0 do
begin
//Result.Add(Copy(Source, SearchPos, FoundAt - SearchPos));
CopyTo.Add(Copy(Source, SearchPos, FoundAt - SearchPos));
SearchPos:= FoundAt + DelLength;
FoundAt:= PosEx(Delimiter, Source, SearchPos);
end;
//Result.Add(Copy(Source, SearchPos, MaxInt));
CopyTo.Add(Copy(Source, SearchPos, MaxInt));
end;[/pascal]


BUT! I'd still like to know why the original doesn't work in the case above ?

[Paulius]

You're creating StringLists inside a loop and try to free them ontside of it, so youre freeing only the last ones

[xGTx]

I thought it'd use the same memory if i used that same StringList, but ok, im going to change up the code a bit when i get home tonight thanks